[Excel]全角英数字のみを半角英数字に変換するHALFWIDTHANカスタムワークシート関数

コード

下記のコードを全てコピーし、標準モジュール等に貼り付けて下さい。下記のコード表示欄の右上に「Copy」ボタンがありますのでご使用下さい。なお、標準モジュールが何だか分からない方は、 Excelのカスタムワークシート関数を使用する方法 を参照して下さい。

' [Excel]全角英数字のみを半角英数字に変換するHALFWIDTHANカスタムワークシート関数 
' Copyright (c) 2020-2024  黒箱 
' This software is released under the MIT License;. 
' このソフトウェアはMITライセンスの下でリリースされています。 

'* @fn Public Function HALFWIDTHAN(ByRef Text As Variant, Optional ByVal ConvertTo7bitSymbols As Boolean = True) As Variant
'* @brief 全角英数字を半角英数字に変換します。全角カタカナは影響を受けません。引数に文字列以外を指定した場合、戻り値は文字列に変換されます。
'* @param[in] Text 変換する文字列を指定します。
'* @param[in] ConvertTo7bitSymbols 7ビット記号( !"#$%&'()*+,-./:;<=>?@[\]^_`{|}~)に対応する全角記号を半角に変換する場合はTRUE、変換しない場合はFALSEを指定します。省略した場合はTRUEが指定されます。
'* @return Variant 変換した文字列を返します。
'*
Public Function HALFWIDTHAN(ByRef Text As Variant, Optional ByVal ConvertTo7bitSymbols As Boolean = True) As Variant
    
    '引数が文字列型以外なら引数を文字列に変換して終了
    If (VarType(Text) <> vbString) Then
        HALFWIDTHAN = CStr(Text)
        Exit Function
    End If
    
    
    '引数が空白のみなら処理なし
    If (Trim(Text) = "") Then
        HALFWIDTHAN = Text
        Exit Function
    End If
    
    
    '変換文字のパターン設定
    Dim Pattern As String   '変換対象文字のパターン(Like右辺値)
    
    If (ConvertTo7bitSymbols) Then
        Static FullWidthANSPattern As String
        If (FullWidthANSPattern = "") Then FullWidthANSPattern = "[　，．：；？！＾＿／～｜‘’" & Chr(-1449) & "（）［-｝＋－＝＜＞￥＄％-＠０-９Ａ-Ｚａ-ｚ]"
        Pattern = FullWidthANSPattern
    Else
        Pattern = "[０-９Ａ-Ｚａ-ｚ]"
    End If
    
    
    '変換
    Dim i As Long
    Dim Char As String      '引数Textの文字を1文字ずつ抽出する際の格納先
    Dim Buffer As String    '引数中の変換対象文字を連結するバッファ
    Dim Result As String    '戻り値
    
    For i = 1 To Len(Text)
        Char = Mid(Text, i, 1)
        
        '引数Text中の連続した変換対象文字をBufferに結合していく。
        If (Char Like Pattern) Then
            Buffer = Buffer & Char
            
        Else '変換対象外の文字を検出したら、Bufferを変換して戻り値に結合。その後ろに変換対象外の文字を結合
            
            'Bufferが空ならStrConv()の呼び出しを省略
            If (Buffer = "") Then
                Result = Result & Char
            Else
                Result = Result & StrConv(Buffer, vbNarrow) & Char
                Buffer = ""
            End If
        End If
    Next i
    
    '引数Textの末尾が変換対象文字の場合は、ループ内の変換処理を通らないため、ここで変換
    If (Buffer <> "") Then
        Result = Result & StrConv(Buffer, vbNarrow)
    End If
    
    HALFWIDTHAN = Result

End Function